home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Collection of Tools & Utilities
/
Collection of Tools and Utilities.iso
/
system
/
tsutld21.zip
/
ADJCURS.BAT
next >
Wrap
DOS Batch File
|
1993-08-15
|
5KB
|
173 lines
echo off
cls
echo ┌─────────────────────────────────────────────────┐
echo │ ADJCURS.BAT Adjust cursor size │
echo │ By Prof. Timo Salmi, ts@uwasa.fi, Sun 15-Aug-93 │
echo └─────────────────────────────────────────────────┘
if "%1"=="" goto _help
rem Establish whether MsDos version 5.0 or later is being used
set isver50_=
ver | find "5.0" > tmpfind.$$$
ver | find "6.0" >> tmpfind.$$$
copy tmpfind.$$$ tmpfind1.$$$ > nul
del tmpfind.$$$
if exist tmpfind1.$$$ set isver50_=yes
if exist tmpfind1.$$$ del tmpfind1.$$$
rem Check that the required files are available
set found_=
if exist mark.com set found_=yes
for %%d in (%path%) do if exist %%d\mark.com set found_=yes
for %%d in (%path%) do if exist %%dmark.com set found_=yes
if not "%found_%"=="yes" goto _err_1
set found_=
if exist bigcurs.exe set found_=yes
for %%d in (%path%) do if exist %%d\bigcurs.exe set found_=yes
for %%d in (%path%) do if exist %%dbigcurs.exe set found_=yes
if not "%found_%"=="yes" goto _err_2
set found_=
if exist bigncurs.exe set found_=yes
for %%d in (%path%) do if exist %%d\bigncurs.exe set found_=yes
for %%d in (%path%) do if exist %%dbigncurs.exe set found_=yes
if not "%found_%"=="yes" goto _err_3
set found_=
if exist release.exe set found_=yes
for %%d in (%path%) do if exist %%d\release.exe set found_=yes
for %%d in (%path%) do if exist %%drelease.exe set found_=yes
if not "%found_%"=="yes" goto _err_4
set found_=
if exist reset.exe set found_=yes
for %%d in (%path%) do if exist %%d\reset.exe set found_=yes
for %%d in (%path%) do if exist %%dreset.exe set found_=yes
if not "%found_%"=="yes" goto _err_5
set found_=
if exist mapmem.exe set found_=yes
for %%d in (%path%) do if exist %%d\mapmem.exe set found_=yes
for %%d in (%path%) do if exist %%dmapmem.exe set found_=yes
if not "%found_%"=="yes" goto _err_7
rem The user's choices
if %1==1 goto _do_1
if %1==2 goto _do_2
if %1==3 goto _do_3
if %1==4 goto _do_4
if %1==5 goto _do_5
if %1==6 goto _do_6
if %1==7 goto _do_7
goto _help
:_do_1
if "%bigcurs_%"=="loaded" goto _notwice
mark bigcurs
if "%isver50_%"=="yes" loadhigh bigcurs
if not "%isver50_%"=="yes" bigcurs
set bigcurs_=loaded
mapmem /u
goto _out
:_do_2
if "%bigcurs_%"=="loaded" goto _notwice
mark bigcurs
if "%isver50_%"=="yes" loadhigh bigcurs m
if not "%isver50_%"=="yes" bigcurs m
set bigcurs_=loaded
mapmem /u
goto _out
:_do_3
if "%bigcurs_%"=="loaded" goto _notwice
bigncurs
goto _out
:_do_4
if "%bigcurs_%"=="loaded" goto _notwice
bigncurs m
goto _out
:_do_5
set bigcurs_=
if "%isver50_%"=="yes" release /u bigcurs
if not "%isver50_%"=="yes" release bigcurs
pause
reset
mapmem /u
goto _out
:_do_6
reset
goto _out
:_do_7
mapmem /u
goto _out
:_err_1
echo File MARK.COM not found in the current directory or at path
echo Cursor size change not implemented
goto _out
:_err_2
echo File BIGCURS.EXE not found in the current directory or at path
echo Cursor size change not implemented
goto _out
:_err_3
echo File BIGNCURS.EXE not found in the current directory or at path
echo Cursor size change not implemented
goto _out
:_err_4
echo File RELEASE.EXE not found in the current directory or at path
echo Cursor size restoration not implemented
goto _out
:_err_5
echo File RESET.EXE not found in the current directory or at path
echo The file RESET.EXE is part of the tsutil35.zip (or later) package
echo Cursor size restoration may be incomplete
goto _out
:_err_7
echo File MAPMEM.EXE not found in the current directory or at path
goto _out
:_notwice
echo.
echo The resident BIGCURS has already been loaded
echo Use ADJCURS 5 to remove it from memory
goto _out
:_help
echo Usage: ADJCURS [ChoiceNumber]
echo 1 Big resident cursor
echo 2 Medium resident cursor
echo 3 Big transient cursor
echo 4 Medium transient cursor
echo 5 Restore original cursor for 1 and 2
echo 6 Restore original cursor for 3 and 4
echo 7 Map the resident programs
echo Although BIGCURS.EXE and BIGNCURS.EXE can be used without further
echo utilities, to use *this batch* you must have the TSR Utilities from
echo TurboPower Software. In particular you'll need the programs MARK.EXE,
echo RELEASE.EXE, and MAPMEM.EXE. Another utility that is necessary for this
echo batch, is RESET.EXE by Timo Salmi. You should be able to obtain them by
echo downloading TSRCOM34.ZIP and TSUTIL38.ZIP (or later) from any well-stocked
echo BBS or FTP site, such as garbo.uwasa.fi, 128.214.87.1, Vaasa, Finland.
echo.
echo If you have MsDos 5.0 or later, ADJCURS.BAT loads the resident cursor high.
echo.
echo Warning, it is not advisable to load the resident cursor more than once.
goto _out
:_out
set isver50_=
set found_=
echo on